JavaScript 2.0 Parser Grammar

This LALR(1) grammar describes the syntax of the JavaScript 2.0 proposal. The starting nonterminal is Program. See also the description of the grammar notation.

Terminals

Punctuation tokens: ! != !== % %= & && &= ( ) * *= + ++ += , - -- -= . .. ... / /= : :: ; < << <<= <= = == === > >= >> >>= >>> >>>= ? @ [ ] ^ ^= { | |= || } ~

Reserved words: break case catch class const continue default delete do else eval extends false field final finally for function if import in instanceof new null package private protected public return super switch this throw true try typeof var while with

Future reserved words: abstract debugger enum export goto implements native static synchronized throws transient volatile

Non-reserved words: constructor getter method override setter traditional version

Expressions

Identifiers

Identifier

Identifier

| version

| override

| method

| getter

| setter

| traditional

| constructor

QualifiedIdentifier

Identifier

| QualifiedIdentifier :: Identifier

| ParenthesizedExpression :: Identifier

Primary Expressions

PrimaryExpression^normal

SimpleExpression

| FunctionExpression

| ObjectLiteral

PrimaryExpression^initial SimpleExpression

SimpleExpression

null

| true

| false

| Number

| String

| this

| super

| QualifiedIdentifier

| RegularExpression

| ParenthesizedExpression

| ArrayLiteral

ParenthesizedExpression ( Expression^{normal,allowIn} )

Function Expressions

FunctionExpression

AnonymousFunction

| NamedFunction

Object Literals

ObjectLiteral

{ }

| { FieldList }

FieldList

LiteralField

| FieldList , LiteralField

LiteralField QualifiedIdentifier : AssignmentExpression^{normal,allowIn}

Array Literals

ArrayLiteral

[ ]

| [ ElementList ]

ElementList

LiteralElement

| ElementList , LiteralElement

LiteralElement AssignmentExpression^{normal,allowIn}

Postfix Unary Operators

PostfixExpression^a

FullPostfixExpression^a

| ShortNewExpression

FullPostfixExpression^a

PrimaryExpression^a

| FullNewExpression

| FullPostfixExpression^a MemberOperator

| FullPostfixExpression^a Arguments

| PostfixExpression^a ++

| PostfixExpression^a --

FullNewExpression new FullNewSubexpression Arguments

ShortNewExpression new ShortNewSubexpression

FullNewSubexpression

PrimaryExpression^normal

| FullNewSubexpression MemberOperator

| FullNewExpression

ShortNewSubexpression

FullNewSubexpression

| ShortNewExpression

MemberOperator

[ ArgumentList ]

| . QualifiedIdentifier

| . ParenthesizedExpression

| @ QualifiedIdentifier

| @ ParenthesizedExpression

Arguments ( ArgumentList )

ArgumentList

«empty»

| ArgumentListPrefix

ArgumentListPrefix

AssignmentExpression^{normal,allowIn}

| ArgumentListPrefix , AssignmentExpression^{normal,allowIn}

Prefix Unary Operators

UnaryExpression^a

PostfixExpression^a

| delete PostfixExpression^normal

| typeof UnaryExpression^normal

| eval UnaryExpression^normal

| ++ PostfixExpression^normal

| -- PostfixExpression^normal

| + UnaryExpression^normal

| - UnaryExpression^normal

| ~ UnaryExpression^normal

| ! UnaryExpression^normal

Multiplicative Operators

MultiplicativeExpression^a

UnaryExpression^a

| MultiplicativeExpression^a * UnaryExpression^normal

| MultiplicativeExpression^a / UnaryExpression^normal

| MultiplicativeExpression^a % UnaryExpression^normal

Additive Operators

AdditiveExpression^a

MultiplicativeExpression^a

| AdditiveExpression^a + MultiplicativeExpression^normal

| AdditiveExpression^a - MultiplicativeExpression^normal

Bitwise Shift Operators

ShiftExpression^a

AdditiveExpression^a

| ShiftExpression^a << AdditiveExpression^normal

| ShiftExpression^a >> AdditiveExpression^normal

| ShiftExpression^a >>> AdditiveExpression^normal

Relational Operators

RelationalExpression^a,allowIn

ShiftExpression^a

| RelationalExpression^a,allowIn < ShiftExpression^normal

| RelationalExpression^a,allowIn > ShiftExpression^normal

| RelationalExpression^a,allowIn <= ShiftExpression^normal

| RelationalExpression^a,allowIn >= ShiftExpression^normal

| RelationalExpression^a,allowIn instanceof ShiftExpression^normal

| RelationalExpression^a,allowIn in ShiftExpression^normal

RelationalExpression^a,noIn

ShiftExpression^a

| RelationalExpression^a,noIn < ShiftExpression^normal

| RelationalExpression^a,noIn > ShiftExpression^normal

| RelationalExpression^a,noIn <= ShiftExpression^normal

| RelationalExpression^a,noIn >= ShiftExpression^normal

| RelationalExpression^a,noIn instanceof ShiftExpression^normal

Equality Operators

EqualityExpression^a,b

RelationalExpression^a,b

| EqualityExpression^a,b == RelationalExpression^normal,b

| EqualityExpression^a,b != RelationalExpression^normal,b

| EqualityExpression^a,b === RelationalExpression^normal,b

| EqualityExpression^a,b !== RelationalExpression^normal,b

Binary Bitwise Operators

BitwiseAndExpression^a,b

EqualityExpression^a,b

| BitwiseAndExpression^a,b & EqualityExpression^normal,b

BitwiseXorExpression^a,b

BitwiseAndExpression^a,b

| BitwiseXorExpression^a,b ^ BitwiseAndExpression^normal,b

| BitwiseXorExpression^a,b ^ *

| BitwiseXorExpression^a,b ^ ?

BitwiseOrExpression^a,b

BitwiseXorExpression^a,b

| BitwiseOrExpression^a,b | BitwiseXorExpression^normal,b

| BitwiseOrExpression^a,b | *

| BitwiseOrExpression^a,b | ?

Binary Logical Operators

LogicalAndExpression^a,b

BitwiseOrExpression^a,b

| LogicalAndExpression^a,b && BitwiseOrExpression^normal,b

LogicalOrExpression^a,b

LogicalAndExpression^a,b

| LogicalOrExpression^a,b || LogicalAndExpression^normal,b

Conditional Operator

ConditionalExpression^a,b

LogicalOrExpression^a,b

| LogicalOrExpression^a,b ? AssignmentExpression^normal,b : AssignmentExpression^normal,b

NonAssignmentExpression^a,b

LogicalOrExpression^a,b

| LogicalOrExpression^a,b ? NonAssignmentExpression^normal,b : NonAssignmentExpression^normal,b

Assignment Operators

AssignmentExpression^a,b

ConditionalExpression^a,b

| PostfixExpression^a = AssignmentExpression^normal,b

| PostfixExpression^a CompoundAssignment AssignmentExpression^normal,b

CompoundAssignment

*=

| /=

| %=

| +=

| -=

| <<=

| >>=

| >>>=

| &=

| ^=

| |=

Expressions

Expression^a,b

AssignmentExpression^a,b

| Expression^a,b , AssignmentExpression^normal,b

OptionalExpression

Expression^{normal,allowIn}

| «empty»

Type Expressions

TypeExpression^a,b NonAssignmentExpression^a,b

Statements

Statement^d,w

CodeStatement^w

| Definition^d,w

CodeStatement^w

EmptyStatement^w

| ExpressionStatement Semicolon^w

| Block^block

| LabeledStatement^w

| IfStatement^w

| SwitchStatement

| DoStatement Semicolon^w

| WhileStatement^w

| ForStatement^w

| WithStatement^w

| ContinueStatement Semicolon^w

| BreakStatement Semicolon^w

| ReturnStatement Semicolon^w

| ThrowStatement Semicolon^w

| TryStatement

| ImportStatement^w

Semicolon^abbrev

;

| «empty»

Semicolon^{abbrevNonEmpty}

;

| «empty»

Semicolon^{abbrevNoShortIf}

;

| «empty»

Semicolon^full ;

Empty Statement

EmptyStatement^abbrev

;

| «empty»

EmptyStatement^{abbrevNonEmpty} ;

EmptyStatement^{abbrevNoShortIf}

;

| «empty»

EmptyStatement^full ;

Expression Statement

ExpressionStatement Expression^{initial,allowIn}

Block

Block^d { Statements^d }

Statements^d

Statement^d,abbrev

| StatementsPrefix^d Statement^{d,abbrevNonEmpty}

StatementsPrefix^d

Statement^d,full

| StatementsPrefix^d Statement^d,full

Labeled Statements

LabeledStatement^w Identifier : CodeStatement^w

If Statement

IfStatement^abbrev

if ParenthesizedExpression CodeStatement^abbrev

| if ParenthesizedExpression CodeStatement^{abbrevNoShortIf} else CodeStatement^abbrev

IfStatement^{abbrevNonEmpty}

if ParenthesizedExpression CodeStatement^{abbrevNonEmpty}

| if ParenthesizedExpression CodeStatement^{abbrevNoShortIf} else CodeStatement^{abbrevNonEmpty}

IfStatement^full

if ParenthesizedExpression CodeStatement^full

| if ParenthesizedExpression CodeStatement^{abbrevNoShortIf} else CodeStatement^full

IfStatement^{abbrevNoShortIf} if ParenthesizedExpression CodeStatement^{abbrevNoShortIf} else CodeStatement^{abbrevNoShortIf}

Switch Statement

SwitchStatement

switch ParenthesizedExpression { }

| switch ParenthesizedExpression { CaseGroups LastCaseGroup }

CaseGroups

«empty»

| CaseGroups CaseGroup

CaseGroup CaseGuards CaseStatementsPrefix

LastCaseGroup CaseGuards CaseStatements

CaseGuards

CaseGuard

| CaseGuards CaseGuard

CaseGuard

case Expression^{normal,allowIn} :

| default :

CaseStatements

CodeStatement^abbrev

| CaseStatementsPrefix CodeStatement^{abbrevNonEmpty}

CaseStatementsPrefix

CodeStatement^full

| CaseStatementsPrefix CodeStatement^full

Do-While Statement

DoStatement do CodeStatement^{abbrevNonEmpty} while ParenthesizedExpression

While Statement

WhileStatement^w while ParenthesizedExpression CodeStatement^w

For Statements

ForStatement^w

for ( ForInitializer ; OptionalExpression ; OptionalExpression ) CodeStatement^w

| for ( ForInBinding in Expression^{normal,allowIn} ) CodeStatement^w

ForInitializer

«empty»

| Expression^normal,noIn

| VariableDefinitionKind VariableBindingList^noIn

ForInBinding

PostfixExpression^normal

| VariableDefinitionKind VariableBinding^noIn

With Statement

WithStatement^w with ParenthesizedExpression CodeStatement^w

Continue and Break Statements

ContinueStatement continue OptionalLabel

BreakStatement break OptionalLabel

OptionalLabel

«empty»

| Identifier

Return Statement

ReturnStatement return OptionalExpression

Throw Statement

ThrowStatement throw Expression^{normal,allowIn}

Try Statement

TryStatement

try Block^block CatchClauses

| try Block^block FinallyClause

| try Block^block CatchClauses FinallyClause

CatchClauses

CatchClause

| CatchClauses CatchClause

CatchClause catch ( TypedIdentifier^allowIn ) Block^block

FinallyClause finally Block^block

Import Statement

ImportStatement^abbrev

import ImportList Semicolon^abbrev

| import ImportList Block^block

| import ImportList Block^block else CodeStatement^abbrev

ImportStatement^{abbrevNonEmpty}

import ImportList Semicolon^{abbrevNonEmpty}

| import ImportList Block^block

| import ImportList Block^block else CodeStatement^{abbrevNonEmpty}

ImportStatement^{abbrevNoShortIf}

import ImportList Semicolon^{abbrevNoShortIf}

| import ImportList Block^block else CodeStatement^{abbrevNoShortIf}

ImportStatement^full

import ImportList Semicolon^full

| import ImportList Block^block

| import ImportList Block^block else CodeStatement^full

ImportList

ImportItem

| ImportList , ImportItem

ImportItem

ImportSource

| Identifier = ImportSource

| protected Identifier = ImportSource

ImportSource

NonAssignmentExpression^normal,noIn

| NonAssignmentExpression^normal,noIn : Version

Definitions

Definition^d,w

Visibility GlobalDefinition^w

| LocalDefinition^d,w

GlobalDefinition^w

VersionDefinition Semicolon^w

| VariableDefinition Semicolon^w

| FunctionDefinition

| MemberDefinition^w

| ClassDefinition

LocalDefinition^top,w

VersionDefinition Semicolon^w

| VariableDefinition Semicolon^w

| FunctionDefinition

| ClassDefinition

LocalDefinition^class,w

VariableDefinition Semicolon^w

| FunctionDefinition

| MemberDefinition^w

| ClassDefinition

LocalDefinition^block,w

VariableDefinition Semicolon^w

| FunctionDefinition

Visibility Specifications

Visibility

private

| package

| public VersionsAndRenames

VersionsAndRenames

«empty»

| VersionsAndRenamesPrefix

VersionsAndRenamesPrefix

VersionRangeAndAlias

| VersionsAndRenamesPrefix , VersionRangeAndAlias

VersionRangeAndAlias

VersionRange

| VersionRange : Identifier

VersionRange

Version

| OptionalVersion .. OptionalVersion

Versions

OptionalVersion

Version

| «empty»

Version Definition

VersionDefinition

version Version

| version Version > VersionList

| version Version = Version

VersionList

Version

| VersionList , Version

Variable Definition

VariableDefinition VariableDefinitionKind VariableBindingList^allowIn

VariableDefinitionKind

var

| const

VariableBindingList^b

VariableBinding^b

| VariableBindingList^b , VariableBinding^b

VariableBinding^b TypedIdentifier^b VariableInitializer^b

TypedIdentifier^b

Identifier

| TypeExpression^normal,b Identifier

VariableInitializer^b

«empty»

| = AssignmentExpression^normal,b

Function Definition

FunctionDefinition

NamedFunction

| getter NamedFunction

| setter NamedFunction

| TraditionalFunction

AnonymousFunction function FunctionSignature Block^block

NamedFunction function Identifier FunctionSignature Block^block

FunctionSignature ParameterSignature ResultSignature

ParameterSignature ( Parameters )

Parameters

«empty»

| RestParameter

| RequiredParameters

| OptionalParameters

| RequiredParameters , RestParameter

| OptionalParameters , RestParameter

RequiredParameters

RequiredParameter

| RequiredParameters , RequiredParameter

OptionalParameters

OptionalParameter

| RequiredParameters , OptionalParameter

| OptionalParameters , OptionalParameter

RequiredParameter TypedIdentifier^allowIn

OptionalParameter

TypedIdentifier^allowIn =

| TypedIdentifier^allowIn = AssignmentExpression^{normal,allowIn}

RestParameter

...

| ... Identifier

ResultSignature

«empty»

| TypeExpression^{initial,allowIn}

TraditionalFunction traditional function Identifier ( TraditionalParameterList ) Block^block

TraditionalParameterList

«empty»

| TraditionalParameterListPrefix

TraditionalParameterListPrefix

Identifier

| TraditionalParameterListPrefix , Identifier

Class Member Definitions

MemberDefinition^w

FieldDefinition Semicolon^w

| MethodDefinition^w

| ConstructorDefinition

FieldDefinition field VariableBindingList^allowIn

MethodDefinition^w

ConcreteMethodDefinition

| AbstractMethodDefinition^w

ConcreteMethodDefinition MethodPrefix Identifier FunctionSignature Block^block

AbstractMethodDefinition^w MethodPrefix Identifier FunctionSignature Semicolon^w

MethodPrefix

MethodKind

| override MethodKind

| final MethodKind

| final override MethodKind

MethodKind

method

| getter method

| setter method

ConstructorDefinition constructor ConstructorName ParameterSignature Block^block

ConstructorName

new

| Identifier

Class Definition

ClassDefinition

class Identifier Superclasses Block^class

| class extends TypeExpression^{initial,allowIn} Block^class

Terminals

Expressions

Identifiers

Primary Expressions

Function Expressions

Object Literals

Array Literals

Postfix Unary Operators

Prefix Unary Operators

Multiplicative Operators

Additive Operators

Bitwise Shift Operators

Relational Operators

Equality Operators

Binary Bitwise Operators

Binary Logical Operators

Conditional Operator

Assignment Operators

Expressions

Type Expressions

Statements

Empty Statement

Expression Statement

Block

Labeled Statements

If Statement

Switch Statement

Do-While Statement

While Statement

For Statements

With Statement

Continue and Break Statements

Return Statement

Throw Statement

Try Statement

Import Statement

Definitions

Visibility Specifications

Versions

Version Definition

Variable Definition

Function Definition

Class Member Definitions

Class Definition

Programs